[Metalab] Morse-Code

[Ralf Schlatterbeck]

On Tue, Jul 12, 2011 at 02:08:50PM +0200, Roland wrote:

> > http://linux.die.net/man/7/cw
> Ja, das ist wohl das einfachste

Oder Du verwendest mein sed-script um Morse-Code zu decodieren, das hab
ich vor Jahren mal geschrieben als es noch im Usenet
rec.radio.amateur.shortwave gab... Da ist regelmässig mal eine
Diskussion ausgebrochen die mit Punkten und Strichen anfing und dann mit
Dits und Dahs geendet hat (die zitierte Manaualpage sagt ja, dass man
sich CW als Töne vorstellen solle).

Script anbei.

BTW: Es gibt ja die Metalab Funkamateure "Metafunk", wir treffen uns
morgen abend und stellen alles rund um Software Defined Radio vor.

http://metalab.at/wiki/MetaFunk

Man muss übrigens *keine* Morseprüfung mehr machen wenn man Funkamateur
werden will... (ich kanns auch nicht wirklich :)

Ralf
-- 
Ralf Schlatterbeck             email: ralf at zoo.priv.at
-------------- next part --------------
#!/bin/sed -f
s/\([^-._ ]\)\./\1/g
s/\([^-._ ]\)-/\1/g
s/\([^iath> ]\)da/\1/g
s/\([^iath> ]\)di/\1/g
s/\([^iath> ]\)Da/\1/g
s/\([^iath> ]\)Di/\1/g
s/da\([^Ddah ]\)/\1/g
s/di\([^dDit ]\)/\1/g
s/Da\([^Ddah ]\)/\1/g
s/Di\([^dDit ]\)/\1/g
s/beep[ ]*/./g
s/beee*p[ ]*/-/g
s/,/ /g
s/di/./g
s/Di/./g
s/da/-/g
s/Da/-/g
s/t//g
s/h//g
s/_/-/g
s/[^-. ]/ /g
s/$/ /
s/\.\.\.-\.\.- /$/g
s/\.\.--\.\. /?/g
s/\.\.--\.- /_/g
s/\.-\.\.-\. /"/g
s/\.-\.-\.- /(period)/g
s/\.----\. /'/g
s/-\.\.\.\.- /(dash)/g
s/-\.-\.-\. /;/g
s/-\.--\.- /)/g
s/--\.\.-- /,/g
s/---\.\.\. /:/g
s/\.\.\.\.\. /5/g
s/\.\.\.\.- /4/g
s/\.\.\.-- /3/g
s/\.\.--- /2/g
s/\.-\.-\. /+/g
s/\.---- /1/g
s/-\.\.\.\. /6/g
s/-\.\.\.- /=/g
s/-\.\.-\. /\//g
s/-\.--\. /(/g
s/--\.\.\. /7/g
s/---\.\. /8/g
s/----\. /9/g
s/----- /0/g
s/\.\.\.\. /h/g
s/\.\.\.- /v/g
s/\.\.-\. /f/g
s/\.-\.\. /l/g
s/\.--\.-\. /@/g
s/\.--\. /p/g
s/\.--- /j/g
s/-\.\.\. /b/g
s/-\.\.- /x/g
s/-\.-\. /c/g
s/-\.-- /y/g
s/--\.\. /z/g
s/--\.- /q/g
s/\.\.\. /s/g
s/\.\.- /u/g
s/\.-\. /r/g
s/\.-- /w/g
s/-\.\. /d/g
s/-\.- /k/g
s/--\. /g/g
s/--- /o/g
s/\.\. /i/g
s/\.- /a/g
s/-\. /n/g
s/-- /m/g
s/\. /e/g
s/- /t/g
s/(period)/./g
s/(dash)/-/g